The Portable Freeware Collection Forums

Code: Select all

@ECHO OFF
:: This script must be placed in the same dir as KeePass.exe
:: and invoked on KeePass' exit. Additionally, sub-dirs named
:: 'backups' and 'xtra' must be present, with '7za.exe',
:: 'scp.exe', 'vssserv.dll', and 'vssxp.dll' inside 'xtra'.
:: '7za.exe' is the command line version of 7Zip
:: http://www.7zip.org/
:: Other files are part of Runtime's ShadowCopy
:: http://www.runtime.org/shadow-copy.htm

setlocal

:: Set today's date string
SET present=%date:-=%

:: Check for existence of today's backup
PUSHD backups
FOR %%f IN (%present%*) DO SET todayfile=%%f
POPD

:: Compute partial filename string
SET now=%time:~0,8%
SET now=%now::=%
IF "%now:~0,1%" == " " SET "now=0%now:~1,7%"

:: If today's local backup exists, skip to file copy
IF NOT "%todayfile%" == "" GOTO update

:: Execute today's backup and log all output
xtra\7za.exe a -y .\backups\%present%%now%.7z *.kdb 2>&1> backups\%present%%now%.log

:update
:: Copy database file to Dropbox and log output
START /MIN xtra\scp.exe "%~dp0*.kdb" "DRIVE:\PATH\TO\Dropbox" /y /r && ECHO. >> backups\%present%%now%.log ^
& ECHO + Dropbox updated! >> backups\%present%%now%.log